Guides
Start typing to search…

KQL Search

The AI Studio LABEL and USE pages support KQL search—a powerful yet simple language that helps you find exactly what you need, faster.


Format:

[NOT] business_values.["keywords" | "numbers" | "dates"]:{key: "x.y.z.{…}" [and | or] value:{number, string}}···

Key Search Features Supports:

  • Nested values search
  • String, Numbers, Date filtering
  • AND, OR, NOT conditions
  • Equal, Greater than, Less than and Between comparisons

Query Examples

Searching extract File by document ids:

  1. Search by document id from BGL Document Service (which is normally called 'bglGRID')

source.external_id:"bglGRID"

example:

source.external_id:"69402d9a-e0ea-4790-925b-dc13e5143c86"


  1. Search by document id from ai studio db (which is normally called ‘sdID' or ai studio 'fileID’)

id:"projectid_SDfileID"

note: you need to also include the AI studio project ID (i.e. the project in Ai studio that you are searching the file, you can find project ID from URL - see screenshot)

example:

id:"2G45TfkiEfcGCY_2025-07-31T07:47:15.200Z_2ae19dcf-80e1-4847-86c9-eca5c64795e6"

Other Common Searching Queries

Search by user

source.user: "[email protected]"


Search by Upload Source

source.source: "xxxx"


Search by Firm ID

source.group1: "xxxx"

Search by Entity ID

source.group2: "xxxx"

** Search by number of pages**

file.pages > 50

Bank Statement Searching Queries

Search Bank Statements using AIWithTable

business_values.keywords:{key:"BankName" and value:"AIWithTable"}

Search Bank Statements NOT using AIWithTable

NOT (business_values.keywords:{key:"BankName" and value:"AIWithTable"})

Search Bank Statements using MacQuarie Or Bendigo

business_values.keywords:{key:"BankName" and (value:"MacQuarie Bank Statement" or value: "Bendigo")}

Search Bank Statements with BSB: 000001 and AccountNumber: 111111111

business_values.keywords:{key:"TransactionTables.BsbAccountNumber.Bsb" and value:"000001"} and business_values.keywords:{key:"TransactionTables.BsbAccountNumber.AccountNumber" and value:"111111111"}

Search Bank Statement with a Credit equals to 5000

business_values.numbers:{key:"TransactionTables.Table.DataRows.Credit" and value:5000}

Search Bank Statement with a Credit NOT equals to 5000

Not (business_values.numbers:{key:"TransactionTables.Table.DataRows.Credit" and value:5000})

Search Bank Statement with a Debit between 1 to 10

business_values.numbers:{key:"TransactionTables.Table.DataRows.Debit" and value >= 1 and value <=10 }

Search Bank Statement with a Transaction Date equals to 2021-02-02

business_values.dates:{key:"TransactionTables.Table.DataRows.TransactionDate" and value:"2021-02-02"}

Search Bank Statement with a Transaction Date later 2021-02-02

business_values.dates:{key:"TransactionTables.Table.DataRows.TransactionDate" and value > "2021-02-02"}

Search Bank Statement with a Transaction Date for FY2021

business_values.dates:{key:"TransactionTables.Table.DataRows.TransactionDate" and value >= "2021-07-01" and value <= "2022-06-30"}


Filter by Time Range

Due to AI Studio UI limitations, the date filters may default to only the last few days. If you're retrieving historical file(s), please remember to update the date filters as shown below.

  • File Created
  • File Updated

Updated 6 days ago